REM Windows 7 Beispiel-Logon-Skript.
 
:winnt
 
echo off

REM Beende das Skript auf Windows-Versionen vor 2000.
if NOT "%OS%"=="Windows_NT" goto winnt_end

REM Servername wird aus dem Programmaufrufpfad extrahiert.
set UNC=%0%
for /f "tokens=1 delims=\" %%i in ("%UNC%") do set SERVER=%%i
if "%SERVER%"=="" goto winnt_end

REM Name des Vorlagenbenutzers. Bitte ändern falls nicht pgmadmin.
set TEMPLATE=pgmadmin

REM Falls nicht vorhanden werden die persönlichen Ordner im Laufwerk H: erstellt.
REM Die Bibliotheks-Ordner gleichen Namens im Windows-Explorer verweisen auf diese Ordner. 
for %%i in (Dokumente Musik Bilder Videos) do if not exist "H:\Eigene %%i" md "H:\Eigene %%i"

REM Die folgenden Anpassungen nicht für den Vorlagenbenutzer durchführen.
if "%USERNAME%"=="%TEMPLATE%" goto winnt_end

REM Beende das Skript, falls der Ordner mit dem Benutzerprofil (C:\Users\<Benutzername>)
REM nicht existiert.
if NOT exist "%USERPROFILE%" goto winnt_end

REM Wechsle ins Benutzerprofilverzeichnis
cd "%USERPROFILE%"

REM Im Folgenden wird in der Registry der Profilpfad des Vorlagenbenutzers durch
REM denjenigen des aktuellen Benutzers ersetzt.

REM Registry-Zweig wird in Textdatei exportiert.
reg export "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" %USERNAME%.reg /y

REM Das VB-Skript replace.vbs ersetzt den Benutzernamen in der exportierten Datei.
cscript \\%SERVER%\netlogon\replace.vbs \\"%TEMPLATE%"\\ \\"%USERNAME%"\\ %USERNAME%.reg

REM Geänderte Registry-Datei wird wieder importiert.
reg import %USERNAME%.reg

REM Weitere Registry-Zweige werden auf diesselbe Weise geändert.
reg export "HKCU\Control Panel\Desktop" %USERNAME%.reg /y
cscript \\%SERVER%\netlogon\replace.vbs \\"%TEMPLATE%"\\ \\"%USERNAME%"\\ %USERNAME%.reg
reg import %USERNAME%.reg
 
reg export "HKCU\Software\Microsoft\GDIPlus" %USERNAME%.reg /y
cscript \\%SERVER%\netlogon\replace.vbs \\"%TEMPLATE%"\\ \\"%USERNAME%"\\ %USERNAME%.reg
reg import %USERNAME%.reg
 
reg export "HKCU\Software\Microsoft\MediaPlayer\Preferences" %USERNAME%.reg /y
cscript \\%SERVER%\netlogon\replace.vbs \\"%TEMPLATE%"\\ \\"%USERNAME%"\\ %USERNAME%.reg
reg import %USERNAME%.reg
 
reg export "HKCU\Software\Microsoft\Windows\CurrentVersion\Themes" %USERNAME%.reg /y
cscript \\%SERVER%\netlogon\replace.vbs \\"%TEMPLATE%"\\ \\"%USERNAME%"\\ %USERNAME%.reg
reg import %USERNAME%.reg
 
reg export "HKCU\Software\Microsoft\Windows Media\WMSDK\Namespace" %USERNAME%.reg /y
cscript \\%SERVER%\netlogon\replace.vbs \\"%TEMPLATE%"\\ \\"%USERNAME%"\\ %USERNAME%.reg
reg import %USERNAME%.reg

REM Datei wird nicht mehr benötigt.
del %USERNAME%.reg
 
:winnt_end
